下面用一個Function來實作.NET中所有的SHA加密

using System;
using System.Security.Cryptography;
using System.Text;

namespace SystemAPI.Function.EncryptLibrary
{
    public class EncryptSHA
    {
        /// <summary>
        /// 使用SHA加密訊息
        /// </summary>
        /// <param name="sourceMessage">原始資訊</param>
        /// <param name="SHAType">SHA加密方式</param>
        /// <returns>string</returns>
        public string Encrypt(string sourceMessage, EnumSHAType SHAType)
        {
            if (string.IsNullOrEmpty(sourceMessage))
            {
                return string.Empty;
            }

            //字串先轉成byte[]
            byte[] Message = Encoding.Unicode.GetBytes(sourceMessage);
            HashAlgorithm HashImplement = null;

            //選擇要使用的SHA加密方式
            switch (SHAType)
            {
                case  EnumSHAType.SHA1:
                    HashImplement = new SHA1Managed();
                    break;
                case EnumSHAType.SHA256:
                    HashImplement = new SHA256Managed();
                    break;
                case EnumSHAType.SHA384:
                    HashImplement = new SHA384Managed();
                    break;
                case EnumSHAType.SHA512:
                    HashImplement = new SHA512Managed();
                    break;
            }

            //取Hash值
            byte[] HashValue = HashImplement.ComputeHash(Message);

            //把byte[]轉成string後，再回傳
            return BitConverter.ToString(HashValue).Replace("-","").ToLower();

        }

        public enum EnumSHAType
        {
            SHA1,
            SHA256,
            SHA384,
            SHA512
        }

    }
}

.
使用方式如下：

EncryptSHA SHA = new EncryptSHA();
string EncryptString = SHA.Encrypt("12345", EncryptSHA.EnumSHAType.SHA512);

雖然還是測試版，不過至少踏出了第一步了吶

下載的名稱為：
32-bit Oracle Data Access Components (ODAC)
for Microsoft Entity Framework and LINQ to Entities 

想嘗鮮的朋友可以先玩看看

參考資料：
Tutorial. Entity Framework, LINQ and Model-First for the Oracle Database

不要怕，以下我問白話文解釋一下 

把繼承建構子分解後，就是 繼承 + 建構子 

繼承，相信有物件導向概念的朋友應該都知道這2個字的意思 

建構子(Constructor)，就是用來進行物件初始化的方法 

一般來說，Class B 繼承 Class A 之後就可以使用Class A所開放出來的東西 

那麼如果Class B 繼承 Class A後，想要對Class A進行初始化的動作，那就需要使用繼承建構子了 

先來看看程式吧，看程式就比較不會那麼文謅謅了。程式碼可於這邊下載(C#、VB.NET雙版本)

首先有一個最基本的Class，我們叫它Class A 

C#版本Class A 

class ClassA
{
    public ClassA()
    {
        _InitString = "123";
    }

    public ClassA(string initStr)
    {
        _InitString = initStr;
    }

    private string _InitString;
    public string InitString
    {
        get { return _InitString; }
    }

    public void ShowClassAInit()
    {
        Console.WriteLine(InitString);
        Console.WriteLine("-----------------------------");
    }
}

VB.NET版本Class A 

Class ClassA
    Public Sub New()
        _InitString = "123"
    End Sub

    Public Sub New(ByVal initStr As String)
        _InitString = initStr
    End Sub

    Private _InitString As String
    Public ReadOnly Property InitString() As String
        Get
            Return _InitString
        End Get
    End Property

    Public Sub ShowClassAInit()
        Console.WriteLine(InitString)
        Console.WriteLine("-----------------------------")
    End Sub
End Class

接下來我們需要Class B來繼承Class A 

注意到了嗎，繼承建構子的實作方式就是於Class B加入一個與Class A一樣的初始建構子

並使用base(C#語法)、MyBase.New(VB.NET語法)把初始值帶入Class A。成功於Class B內，進行初始化Class A的動作 

C#版本Class B 

class ClassB : ClassA
{
    public ClassB()
    {        
    }

    public ClassB(string initStr)
        : base(initStr)
    {           
    }        
}

VB.NET版本Class B 

Class ClassB
    Inherits ClassA

    Public Sub New()
    End Sub

    Public Sub New(ByVal initStr As String)
        MyBase.New(initStr)
    End Sub

End Class

接下來就看看怎麼使用，跟使用的結果吧
下面使用Console來DemoC#版本Console 

 

class Program
{
    static void Main(string[] args)
    {
        ClassA CA1 = new ClassA();
        Console.WriteLine("new ClassA()");
        CA1.ShowClassAInit(); //Result:123 

        ClassA CA2 = new ClassA("Init AAA");
        Console.WriteLine("new ClassA(\"Init AAA\")");
        CA2.ShowClassAInit(); //Result:Init AAA 

        ClassB CB1 = new ClassB();
        Console.WriteLine("new ClassB()");
        CB1.ShowClassAInit(); //Result:123 

        ClassB CB2 = new ClassB("Init BBB");
        Console.WriteLine("new ClassB(\"Init BBB\")");
        CB2.ShowClassAInit(); //Result:Init BBB 

        Console.ReadLine();
    }
} 

VB.NET版本Console 

 

Module Module1 

    Sub Main()
        Dim CA1 As New ClassA()
        Console.WriteLine("new ClassA()")
        CA1.ShowClassAInit()  'Result:123 

        Dim CA2 As New ClassA("Init AAA")
        Console.WriteLine("new ClassA(""Init AAA"")")
        CA2.ShowClassAInit()  'Result:Init AAA 

        Dim CB1 As New ClassB
        Console.WriteLine("new ClassB()")
        CB1.ShowClassAInit()  'Result:123 

        Dim CB2 As New ClassB("Init BBB")
        Console.WriteLine("new ClassB(""Init BBB"")")
        CB2.ShowClassAInit()  'Result:Init BBB 

        Console.ReadLine() 

    End Sub 

End Module 

執行結果如下圖

以上程式碼可於這邊下載(C#、VB.NET雙版本)

都會使用「@」這個好用的符號。好處就是可以直接斷行

例如：
string test = @"
select * from tb
where c1 = 123"

但是在VB.NET就要很鱉腳用 「 & _ 」來斷行
例如：
dim test as string
test = "select * from tb" & _
"where c1 = 123"

如果行數一多，那可真是累死人不償命又無聊的工程
某天在黑暗執行緒的某一篇文章挖到了寶

使用VB.NET 2008內建的XML嵌入語法，來達成模擬C#的「@」
直接看下面的例子

        Dim JS As String = <s><![CDATA[
                <script type="text/javascript">
                jQuery(function ($) {
                    $('#@txtbox.ClientID@').datepicker({
                    rangeSelect: true,
                    firstDay: 1,
                    changeMonth: true,
                    changeYear: true,
                    showOn: 'both',
                    buttonImageOnly: true,
                    buttonImage: '@Context.Request.ApplicationPath@/Picture/calendar.gif'
                    });
                });
                </script>
        ]]></s>.Value.Replace(vbLf, vbCrLf)

跟據Ark網友的補充，由於預設的換行是vbLf，所以後面我加了Replace(vbLf, vbCrLf)
來把換行符號變成vbCrLf

那如果字串裡面有變數怎麼辦?
先把變數用@包起來，例如：@txtbox.ClientID@
之後再用Replace去把變數塞進去，例如：JS = JS.Replace("@txtbox.ClientID@", "AAAA")

看來一切都很完美了，不過還沒結束
當你在VS2010上使用時你會發現字串內的文字是接近白色的
這對老人家的眼力是很大的考驗

這時候可以進去選項裡面調整

選擇字型與色形，再挑選VB XML CData 區段，調整你想要顏色，按下確定

收工

答案就是使用 Obsolete 這個屬性
先來看看範例程式碼

VB.NET 的語法如下

    Partial Public Class GetDirectoryFiles
        ''' <summary>
        ''' 取得資料夾與檔案
        ''' </summary>
        ''' <returns>String</returns>
        ''' <remarks></remarks>
        <Obsolete("這個方法已經過時了，建議使用新的方法GetDF()")> _
        Public Function GetDirectoryFile() As String
            Return ""
        End Function
    End Class

C# 的語法如下

public partial class GetDirectoryFiles
{
	/// <summary>
	/// 取得資料夾與檔案
	/// </summary>
	/// <returns>String</returns>
	/// <remarks></remarks>
	[Obsolete("這個方法已經過時了，建議使用新的方法GetDF()")]
	public string GetDirectoryFile()
	{
		return "";
	}
}

當使用者使用到這個方法、函式就會出現下面的提示
提示使用者需要注意一下

如果你安裝完成後，使用Visual Studio 2008建立DocProject專案後
此時可以在Visual Studio內進行建置，並不會有錯誤
但如果是用DocProject External UI來開啟專案你就會收到一個錯誤，像下圖
這是因為程式找不到輸出的路徑

解決方法如下：
1.先使用記事本開啟DocProject的專案檔(csproj 或 vbproj)
2.於第一個<PropertyGroup>內插入<OutputPath>bin\</OutputPath>。如下圖所示

接下來就可以順利使用DocProject External UI了
建置時，別忘了選擇編譯的CPU類型

話不多說了，直接來看程式吧

using System.Xml.Linq;
XDocument XDoc = XDocument.Load(Log4NetConfigXMLFilePath);
var nodes = (from p in XDoc.Elements("log4net")
                  .Elements("appender")
                  .Elements("file")
             elect p).FirstOrDefault();
//使用Linq Select出來後，進行處理
nodes.SetAttributeValue("value",HttpContext.Current.Server.MapPath("~/") +
                                 nodes.Attribute("value").Value);
//轉出來後再放到XmlDocument
System.Xml.XmlDocument XmlDoc = new System.Xml.XmlDocument();
//把XDocument轉成XmlDocument
XmlDoc.LoadXml(XDoc.Document.ToString());

首先新增一個泛型處理常式(ashx)

然後把程式寫在裡面(程式碼請往下看)

最後把Image的Url位置指向我們新增的ashx檔的位置即可

範例程式：測試程式的專案檔

Default.aspx

        '把實體圖片讀成Byte
    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim f As System.IO.FileStream
        f = System.IO.File.OpenRead(HttpContext.Current
                         .Server.MapPath("20100309_1.jpg"))
        Dim b(f.Length) As Byte
        f.Read(b, 0, f.Length - 1)
        Session("pic") = b
    End Sub

Showlogo.ashx

Imports System.Web.SessionState

Public Class Showlogo
    Implements System.Web.IHttpHandler
    Implements IRequiresSessionState

    Sub ProcessRequest(ByVal context As HttpContext) Implements IHttpHandler.ProcessRequest

        Dim b() As Byte = context.Session("pic")

        context.Response.ContentType = "text/jpg"
        context.Response.BinaryWrite(b)

    End Sub

    ReadOnly Property IsReusable() As Boolean Implements IHttpHandler.IsReusable
        Get
            Return False
        End Get
    End Property

End Class

參考資料：
在 HttpHandler 中使用 Session 的注意事項

利用 ASP.NET的泛型處理常式(Handler)產生圖片驗證碼,結合IRequiresSessionState將驗證碼儲存在session裡,透過 session值來驗證

一般在Oracle中要Select Table時，除了自已建的Table外

要Select其他人建的表格，就要像這樣子  Select * from 帳號.Table

如果要去掉這個限制，就使用下面這段語法

grant all on table_name to public;
drop   public synonym table_name;//第一次建立可省略
create public synonym table_name for table_name;

資料來源網站：瓶水相逢.Net

• 一般情況下：

Page.PreInit
Page.Init
Page.InitComplete
Page.PreLoad
Page.Load
Page.LoadComplete
Page.PreRender
Page.PreRenderComplete

• 使用了 MasterPage 情況， MasterPage 與 ContentPage 事件順序：

ContentPage.PreInit
Master.Init
ContentPage.Init
ContentPage.InitComplete
ContentPage.PreLoad
ContentPage.Load
Master.Load
ContentPage.LoadComplete
ContentPage.PreRender
Master.PreRender
ContentPage.PreRenderComplete

參考：
(1) ASP.NET 網頁生命週期概觀
(2) ASP.NET 主版和內容頁面中的事件

微軟官方作法是使用SQL Server當中介站，相關說明可參考這邊

不過考量到不是每個專案都會用到SQL Server，所以參考較為簡單的方式來解決

請參考Transfer Session Variables from Classic ASP to ASP.NET，範例網站內可下載。或由小站這邊下載

不過需注意的地方是，如果你要傳的資料很敏感，那請記得加密後再傳

且為了避免使用者攔劫資料修改，建議是加上檢查碼，或是加密

ASP.NET收到後再解密

相關網站：

Session 共用與跨網域

Transfer Session Variables from Classic ASP to ASP.NET

How to Share Session State Between Classic ASP and ASP.NET

解決ASP與ASP.NET共存於一專案Session共用問題(StateStitch)

這篇文章將實作程式來讀取自然人憑證的卡號

程式參考於使用C#讀取自然人評證卡號

但實作後仍無法正確顯示，所以使用 WinSCard APDU View Utility 來側錄指令後，修改成下面的程式碼

Imports System
Imports System.Text
Imports System.Runtime.InteropServices

Public Class DigitalCard

    Private Structure SCARD_IO_REQUEST
        Public dwProtocol As Integer
        Public cbPciLength As Integer
    End Structure

    '引用 PC/SC(Personal Computer/Smart Card) API WinScard.dll

    <DllImport("WinScard.dll")> _
    Private Shared Function SCardEstablishContext(ByVal dwScope As UInteger, ByVal nNotUsed1 As Integer, ByVal nNotUsed2 As Integer, ByRef phContext As Integer) As Integer
    End Function

    <DllImport("WinScard.dll")> _
    Private Shared Function SCardReleaseContext(ByVal phContext As Integer) As Integer
    End Function

    <DllImport("WinScard.dll")> _
    Private Shared Function SCardConnect(ByVal hContext As Integer, ByVal cReaderName As String, ByVal dwShareMode As UInteger, ByVal dwPrefProtocol As UInteger, ByRef phCard As Integer, ByRef ActiveProtocol As Integer) As Integer
    End Function

    <DllImport("WinScard.dll")> _
    Private Shared Function SCardDisconnect(ByVal hCard As Integer, ByVal Disposition As Integer) As Integer
    End Function

    <DllImport("WinScard.dll")> _
    Private Shared Function SCardListReaders(ByVal hContext As Integer, ByVal cGroups As String, ByRef cReaderLists As String, ByRef nReaderCount As Integer) As Integer
    End Function

    <DllImport("WinScard.dll")> _
    Private Shared Function SCardTransmit(ByVal hCard As Integer, ByRef pioSendPci As SCARD_IO_REQUEST, ByVal pbSendBuffer() As Byte, ByVal cbSendLength As Integer, ByRef pioRecvPci As SCARD_IO_REQUEST, ByRef pbRecvBuffer As Byte, ByRef pcbRecvLength As Integer) As Integer
    End Function

    ''' <summary>
    ''' 取得自然人憑證的卡號
    ''' </summary>
    ''' <returns></returns>
    ''' <remarks></remarks>
    Public Function GetCardNumber() As String
        Dim ContextHandle As Integer = 0, CardHandle As Integer = 0, ActiveProtocol As Integer = 0, ReaderCount As Integer = -1
        Dim ReaderList As String = String.Empty '讀卡機名稱列表
        Dim SendPci, RecvPci As SCARD_IO_REQUEST

        Dim SelEFAPDU_1() As Byte = {&H80, &HA4, &H0, &H0, &H2, &H3F, &H0} 'Select Elementary File 的 APDU
        Dim SelEFAPDU_2() As Byte = {&H80, &HA4, &H0, &H0, &H2, &H9, &H0} 'Select Elementary File 的 APDU
        Dim SelEFAPDU_3() As Byte = {&H80, &HA4, &H0, &H0, &H2, &H9, &H3} 'Select Elementary File 的 APDU

        Dim ReadSNAPDU() As Byte = {&H80, &HB0, &H0, &H0, &H10} '由offset 0 讀取 0x10位 Binary 資料的 APDU

        Dim SelEFRecvBytes(1) As Byte '應回 90 00
        Dim SelEFRecvLength As Integer = 2
        Dim SNRecvBytes(17) As Byte '接收卡號的 Byte Array
        Dim SnRecvLength As Integer = 18

        '建立 Smart Card API
        If SCardEstablishContext(0, 0, 0, ContextHandle) = 0 Then

            '列出可用的 Smart Card 讀卡機
            If SCardListReaders(ContextHandle, Nothing, ReaderList, ReaderCount) = 0 Then

                '建立 Smart Card 連線
                If SCardConnect(ContextHandle, ReaderList, 1, 2, CardHandle, ActiveProtocol) = 0 Then

                    RecvPci.dwProtocol = ActiveProtocol
                    SendPci.dwProtocol = RecvPci.dwProtocol

                    RecvPci.cbPciLength = 8
                    SendPci.cbPciLength = RecvPci.cbPciLength

                    '下達 Select FE14 檔的 APDU
                    If SCardTransmit(CardHandle, SendPci, SelEFAPDU_1, SelEFAPDU_1.Length, RecvPci, SelEFRecvBytes(0), SelEFRecvLength) = 0 Then
                        If SCardTransmit(CardHandle, SendPci, SelEFAPDU_2, SelEFAPDU_2.Length, RecvPci, SelEFRecvBytes(0), SelEFRecvLength) = 0 Then
                            If SCardTransmit(CardHandle, SendPci, SelEFAPDU_3, SelEFAPDU_3.Length, RecvPci, SelEFRecvBytes(0), SelEFRecvLength) = 0 Then

                                '下達讀取卡號指令
                                If SCardTransmit(CardHandle, SendPci, ReadSNAPDU, ReadSNAPDU.Length, RecvPci, SNRecvBytes(0), SnRecvLength) = 0 Then
                                    Return Encoding.Default.GetString(SNRecvBytes, 0, 16)
                                End If
                            End If
                        End If
                    End If
                End If
            End If
        End If
        Return ""
    End Function

End Class

使用的話請參考下面程式

    Private Sub Button1_Click_1(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim DGCard As New DigitalCard
        MsgBox(DGCard.GetCardNumber)
    End Sub

效果就像下面的圖所示，滑鼠所指到的那一列會變成亮黃色，移開後再還原成原本的顏色

以下為程式碼片段，於RowDataBound的事件中綁定JavaScript到Row中

    Private Sub GridView1_RowDataBound(ByVal sender As Object, _
              ByVal e As System.Web.UI.WebControls.GridViewRowEventArgs) _
              Handles GridView1.RowDataBound
        '滑鼠移入移出效果。
        If e.Row.RowType = DataControlRowType.DataRow Then
            e.Row.Attributes.Add("onmouseout", "this.style.backgroundColor=currentcolor;")
            e.Row.Attributes.Add("onmouseover", "currentcolor=this.style.backgroundColor; this.style.backgroundColor='#ffff40';")
        End If
    End Sub

簡單的說就是可以讓你自已擴充用的東西(有說跟沒說一樣.....)

不用把擴充方法想的太難，它其實也是很平易近人的

在寫程式的時候，在字串的後面點(.)下去，會跑出一堆方法讓你使用，最常見的就是ToString()

那麼我們要如何自行設計一個屬於自己的方法呢(結果如下圖)?其實不難

下程的範例程式(專案打包點我下載)，研究一下應該就可以懂了

首先撰寫要自訂擴充的方法 ModuleExt.vb

這邊需要注意的地方，在於傳入的參數型態

如果傳入的參數型態是Integer，那麼只有型態是Integer的點下去才會出這個自訂的Method

如果想要任何型態點下去，都會帶出現我們自定的Method，

那麼就把型態定為Object就可以了(如本例的AddString)

Imports System.Runtime.CompilerServices

Namespace ExtensionMethods
    Module OtherExtensions

        ''' <summary>
        ''' 英文字首轉大寫
        ''' </summary>
        <Extension()> _
        Public Function ToUpperFirstWord(ByVal src As String) As String
            If src.Length >= 1 Then
                Dim FirstWord As String = src.Substring(0, 1).ToUpper
                src = src.Remove(0, 1).Insert(0, FirstWord)
            End If
            Return src
        End Function

        <Extension()> _
        Public Function ToPerCent(ByVal src As Double) As String
            Return src * 100 & "%"
        End Function

        <Extension()> _
        Public Function AddString(ByVal src As Object) As String
            Return src & " New AddString"
        End Function

    End Module
End Namespace

接下來則是在要使用的程式頁面引用之前所寫的Extension

Imports ConsoleApplicationTEST.ExtensionMethods.OtherExtensions

Module Module1

    Sub Main()
        Dim test As String = "abcd"
        'Output: Abcd
        Console.WriteLine(test.ToUpperFirstWord)
        'Output: abcd New AddString
        Console.WriteLine(test.AddString)
        'Output: Abcd New AddString
        Console.WriteLine(test.ToUpperFirstWord.AddString)

        'Output: 50%
        Dim testint As Double = 0.5
        Console.WriteLine(testint.ToPerCent)

        Console.ReadLine()
    End Sub

End Module

相關文章：
何謂擴充方法 (Extension method )？
C# 3.0 初體驗：Extension Method
[C#] 3.0 中的新功能 - 擴充方法(Extension Method)

這幾天摸了一下，感覺上是個還不錯用的元件

尤其對於在開發"編輯環境"的特別好用

簡單的說，這是一個可以幫你把Class變成設定介面的元件

把Class丟進元件後，元件就會幫你處理傳值與顯示值的問題

看圖或許比較好理解

有沒有一種很熟悉的感覺，沒錯，跟 Visual Studio .Net 的的屬性設定是一樣的

而這個介面只要把寫好的Class放進去就可以自動產生了，真的超方便

完整的程式碼可以到這邊下載

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) _
    Handles MyBase.Load
        '把Class丟進去PropertyGrid
        PropertyGrid1.SelectedObject = New SampleClass
    End Sub

SampleClass.vb

Imports System.ComponentModel

Public Class SampleClass

    <FlagsAttribute()> _
   Public Enum Permissions
        <Description("未設定")> _
        None = 0

        <Description("建立")> _
        Create = 1

        <Description("讀取")> _
        Read = 2

        <Description("更新")> _
        Update = 4

        <Description("刪除")> _
        Delete = 8

        <Description("所有功能")> _
        All = Create Or Read Or Update Or Delete

    End Enum

    Private _P1 As String
    Public Property P1_String() As String
        Get
            Return _P1
        End Get
        Set(ByVal value As String)
            _P1 = value
        End Set
    End Property

    Private _P2 As Integer
    Public Property P2_Integer() As Integer
        Get
            Return _P2
        End Get
        Set(ByVal value As Integer)
            _P2 = value
        End Set
    End Property

    Private _P3 As Boolean
    Public Property P3_Boolen() As Boolean
        Get
            Return _P3
        End Get
        Set(ByVal value As Boolean)
            _P3 = value
        End Set
    End Property

    Private _P4 As DateTime
    Public Property P4_DateTime() As DateTime
        Get
            Return _P4
        End Get
        Set(ByVal value As DateTime)
            _P4 = value
        End Set
    End Property

    Private _P5 As Permissions
    Public Property P5_Enum() As Permissions
        Get
            Return _P5
        End Get
        Set(ByVal value As Permissions)
            _P5 = value
        End Set
    End Property

    Private _P6 As New PropertyTreeClass.AddressType
    <DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
    <Description("住址")> _
    Public Property P6_Tree() As PropertyTreeClass.AddressType
        Get
            Return _P6
        End Get
        Set(ByVal value As PropertyTreeClass.AddressType)
            _P6 = value
        End Set
    End Property

    Private _P7 As Color = Color.White
    Public Property P7_Color() As Color
        Get
            Return _P7
        End Get
        Set(ByVal value As Color)
            _P7 = value
        End Set
    End Property

    Private _P8 As Color = System.Drawing.Color.FromArgb(123, 123, 123)
    <Description("於自訂項目的下面空格中按下滑鼠右鍵，可自訂RGB")> _
    Public Property P8_Color() As Color
        Get
            Return _P8
        End Get
        Set(ByVal value As Color)
            _P8 = value
        End Set
    End Property

#Region "可分類的屬性"
    Private _C1 As String
    <Category("分類")> _
    <Description("相同類型的屬性C1")> _
    Public Property C1() As String
        Get
            Return _C1
        End Get
        Set(ByVal value As String)
            _C1 = value
        End Set
    End Property

    Private _C2 As String
    <Category("分類")> _
    <Description("相同類型的屬性C2")> _
    Public Property C2() As String
        Get
            Return _C2
        End Get
        Set(ByVal value As String)
            _C2 = value
        End Set
    End Property
#End Region

End Class

PropertyTreeClass.vb

Imports System.ComponentModel
Imports System.Globalization

'The namespace referenced from
'http://social.msdn.microsoft.com/Forums/en-US/winforms/thread/f81b6caa-5fae-45c4-ad46-2240e84a5d7a

Namespace PropertyTreeClass

    <TypeConverter(GetType(AddressTypeTypeConverter))> _
    Public Class AddressType

        Private m_country As String
        <NotifyParentProperty(True), Description("國家"), RefreshProperties(RefreshProperties.Repaint)> _
        Public Property Country() As String
            Get
                Return m_country
            End Get

            Set(ByVal value As String)
                m_country = value
            End Set
        End Property

        Private m_city As String
        <NotifyParentProperty(True), Description("城市"), RefreshProperties(RefreshProperties.Repaint)> _
        Public Property City() As String
            Get
                Return m_city
            End Get

            Set(ByVal value As String)
                m_city = value
            End Set
        End Property
    End Class

    Public Class Person

        Public Sub New()
            homeAddressField = New AddressType()
        End Sub

        Private homeAddressField As AddressType

        <DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
        Public Property HomeAddress() As AddressType
            Get
                Return Me.homeAddressField
            End Get

            Set(ByVal value As AddressType)
                Me.homeAddressField = value
            End Set
        End Property
    End Class

    Public Class AddressTypeTypeConverter
        Inherits TypeConverter

        Public Overrides Function ConvertTo(ByVal context As ITypeDescriptorContext, ByVal culture As System.Globalization.CultureInfo, ByVal value As Object, ByVal destinationType As Type) As Object
            'This method is used to shown information in the PropertyGrid.
            If destinationType Is GetType(String) Then
                Return (DirectCast(value, AddressType).Country & ",") + DirectCast(value, AddressType).City
            End If

            Return MyBase.ConvertTo(context, culture, value, destinationType)
        End Function

        Public Overrides Function GetProperties(ByVal context As ITypeDescriptorContext, ByVal value As Object, ByVal attributes As Attribute()) As PropertyDescriptorCollection
            Return TypeDescriptor.GetProperties(GetType(AddressType), attributes).Sort(New String() {"Country", "City"})
        End Function

        Public Overrides Function GetPropertiesSupported(ByVal context As ITypeDescriptorContext) As Boolean
            Return True
        End Function

    End Class

End Namespace

<FlagsAttribute()> _
Public Enum Permissions

<Description("未設定")> _
None = 0

<Description("建立")> _
Create = 1

<Description("讀取")> _
Read = 2

<Description("更新")> _
Update = 4

<Description("刪除")> _
Delete = 8

<Description("所有功能")> _
All = Create Or Read Or Update Or Delete

End Enum

'要取得描述時使用下面的程式碼

Dim fi As FieldInfo = _
Permissions.Create.GetType().GetField(Permissions.Create.ToString())

Dim attributes As DescriptionAttribute() = _
CType(fi.GetCustomAttributes(GetType(DescriptionAttribute), False),  _
DescriptionAttribute())

'顯示取得的描述
Response.Write(attributes(0).Description)

應該會是像下面的指令碼一樣

SELECT     TOP (100) PERCENT MsgText
FROM         dbo.RouterOS_All
ORDER BY MsgDateTime DESC

當View建好了，也存檔了之後，再把View開起來

你會發現其實這個View並沒有依照我們的意思Order by

而解決問題的方法就是不要使用PERCENT，改用一個數值很大的值

SELECT     TOP (2147483647) MsgText
FROM         dbo.RouterOS_All
ORDER BY MsgDateTime DESC

這樣子就正常了。至於這是不是個Bug，我想就只能問MS了

測試環境：
SQL Server 2005 Express with SP3
Windows 2008 Std with SP1 x86

參考資料：
SQL Server 2005 Ordered View and Inline Function Problems

花了一些時間寫了一個副程式，有需要的朋友可以拿去使用

如果你需要遞迴尋找的話(即該目錄下的所有子目錄也要找)，把第3參數帶True進去即可

程式使用方式請看下面

'使用方式(只找1層)
Dim files As List(Of FileInfo) = _
GetPathFile(txt_batch_patch.Text, New String() {".png", ".jpg"})

lst_filename.Items.Clear()

For Each s As FileInfo In files
    lst_filename.Items.Add(s.Name)
Next

'使用方式(遞迴尋找)
Dim files As List(Of FileInfo) = _
GetPathFile(txt_batch_patch.Text, New String() {".png", ".jpg"}, True)

lst_filename.Items.Clear()

For Each s As FileInfo In files
    lst_filename.Items.Add(s.Name)
Next

.
.

完整的副程式如下

    ''' <summary>
    ''' 取得目錄下副檔名為特定格式的檔案
    ''' </summary>
    ''' <param name="DirPath">起始目錄</param>
    ''' <param name="file_extension">要尋找的副檔名</param>
    ''' <param name="IsRecursive">是否要尋找子目錄(預設值為不尋找子目錄)</param>
    ''' <returns>List(Of FileInfo)</returns>
    ''' <remarks></remarks>
    Private Function GetPathFile(ByVal DirPath As String, _
                                 ByVal file_extension As String(), _
                                 Optional ByVal IsRecursive As Boolean = False) _
                                 As List(Of FileInfo)

        '取得目錄下所有的資料夾
        Dim DirectoryPath As New List(Of String)
        DirectoryPath = My.Computer.FileSystem.GetDirectories(DirPath).ToList
        Dim Files As New List(Of FileInfo)

        If IsRecursive = True Then
            For Each DirName As String In DirectoryPath
                If System.IO.Directory.Exists(DirName) Then
                    '讓程式不要停止回應
                    Application.DoEvents()
                    '如果存在下一層的資料夾就遞迴呼叫
                    Files.AddRange(GetPathFile(DirName, file_extension, IsRecursive))
                End If
            Next
        End If

        DirectoryPath.Add(DirPath)
        For Each DirStr As String In DirectoryPath

            '取得目錄下所有的檔案名稱(String)
            Dim myFiles = From s In My.Computer.FileSystem.GetFiles(DirStr)

            '先把檔案名稱轉成FileInfo
            Dim f As New List(Of FileInfo)
            For Each s As String In myFiles
                f.Add(My.Computer.FileSystem.GetFileInfo(s))
            Next

            '使用LINQ來取出我們要的資料(副檔名包含在ImageExtension()裡面的)
            Dim files_filter As IEnumerable(Of FileInfo) = _
            From s In f _
            Where file_extension.Contains(s.Extension.ToLower)

            Files.AddRange(files_filter.ToList)

        Next

        Return Files

    End Function

詳細可以參考這篇文章
[KB]如果UpdatePanel有多個觸發來源，要怎麼將內容Post回去原觸發的控制項呢？

這邊列出重點程式碼

    Protected Sub DropDownList1_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs) _
                                                        Handles DropDownList1.SelectedIndexChanged
        Dim tmppce As AjaxControlToolkit.PopupControlExtender
        tmppce = AjaxControlToolkit.PopupControlExtender.GetProxyForCurrentPopup(Page)
        tmppce.Commit(DropDownList1.SelectedValue.ToString())
    End Sub

可以發現回傳的值是寫在元件的事件觸發之中

可是如果我們是使用 UserControl 那該如何解決呢

很簡單，只要在 UserControl 中新增一個事件，並且於 UserControl 觸發該事件就可以了

感覺很像很複雜，其實不會，看程式或許會比較好了解一點

先建立一個 UserControl ，並且加入一個 TreeView 元件

<asp:TreeView ID="TreeView1" runat="server" BackColor="#66FFFF">
    <Nodes>
        <asp:TreeNode Text="測試1" Value="111111">
            <asp:TreeNode Text="測試1_1" Value="新節點"></asp:TreeNode>
        </asp:TreeNode>
        <asp:TreeNode Text="測試2" Value="222222222"></asp:TreeNode>
        <asp:TreeNode Text="測試3" Value="33333"></asp:TreeNode>
    </Nodes>
</asp:TreeView>

然後在 UserControl 中新增一個事件，且設定 TreeView 的 SelectedNodeChanged 會觸發該新增的事件

    Public Event UC_Event(ByVal srt As String)

    Protected Sub TreeView1_SelectedNodeChanged(ByVal sender As Object, ByVal e As EventArgs) _
                                            Handles TreeView1.SelectedNodeChanged
        RaiseEvent UC_Event(TreeView1.SelectedNode.Text)
    End Sub

接下來於主頁面中把該 UserControl 拉進來，然後新增程式於 UC_Event 事件中

  Private Sub UC1_UC_Event(ByVal srt As String) Handles UC1.UC_Event
        Dim tmppce As AjaxControlToolkit.PopupControlExtender
        tmppce = AjaxControlToolkit.PopupControlExtender.GetProxyForCurrentPopup(Page)
        tmppce.Commit(srt)
    End Sub

這樣子我們就有一個可以在 PopupControlExtender 放入 UserControl ，而且也可以有回傳值了

很多都用的到，例如：LDAP 上的密碼加密

那麼要如何在 .net 上實現這個函式呢

其實已經有人寫好，等我們去用了

A C# implementation of Unix crypt()

把原始檔案下載下來後是個 C# 的程式檔

先在 Visual Studio 中開一個新類別庫專案(C#)，把檔案加入

然後就可以建成 dll 檔來使用了

本來有想說改成 VB.Net 的版本，不過轉換過後有些地方怪怪的就放棄了

這邊有打包好的版本，有興趣的可以下載回去研究